One Hat Cyber Team

Your IP: 160.79.111.165
Server IP: 15.204.235.159
Server: Linux srv.techlup.co.ke 4.18.0-553.5.1.el8_10.x86_64 #1 SMP Wed Jun 5 09:12:13 EDT 2024 x86_64
Server Software: Apache
PHP Version: 8.2.27
Buat File | Buat Folder

Dir : ~/proc/self/root/usr/share/zsh/site-functions/

Edit File: _coredumpctl

#compdef coredumpctl
# SPDX-License-Identifier: LGPL-2.1+

_coredumpctl_command(){
    local -a _coredumpctl_cmds
    _coredumpctl_cmds=(
            'list:List available coredumps'
            'info:Show detailed information about one or more coredumps'
            'dump:Print coredump to stdout'
            'gdb:Start gdb on a coredump'
    )
    if (( CURRENT == 1 )); then
        _describe -t commands 'coredumpctl command' _coredumpctl_cmds
    else
        local curcontext="$curcontext"
        local -a _dumps
        cmd="${${_coredumpctl_cmds[(r)$words[1]:*]%%:*}}"
        if (( $#cmd  )); then
            _dumps=( "${(f)$(coredumpctl list --no-legend | awk 'BEGIN{OFS=":"} {sub(/[[ \t]+/, ""); print $4,$0}' 2>/dev/null)}" )
            if [[ -n "$_dumps" ]]; then
                _describe -V -t pids 'coredumps' _dumps
            else
                _message "no coredumps"
            fi
        else
            _message "no more options"
        fi
    fi
}

_arguments \
    {-o+,--output=}'[Write output to FILE]:output file:_files' \
    {-F+,--field=}'[Show field in list output]:field' \
    '-1[Show information about most recent entry only]' \
    {-S,--since}'[Print entries since the specified date]' \
    {-U,--until}'[Print entries until the specified date]' \
    {-r,--reverse}'[Show the newest entries first]' \
    '--no-pager[Do not pipe output into a pager]' \
    '--no-legend[Do not print the column headers]' \
    {-h,--help}'[Show this help]' \
    '--version[Show package version]' \
    '*::coredumpctl commands:_coredumpctl_command'